# Supplemental .ircrc file for DALnet
# Originally compiled by MirclMax (spike@dal.net)
# Modified by Wizzu (Mikko.Hanninen@iki.fi)

# The following make use of the time/date stamping methods used on the DALnet
# servers. They will not interfere with anything on any other net.

on ^367 * if ([$4] != []) {echo ### $1 \($3 - $stime($4)) $2} {echo ### $1-}
#on ^333 * echo ### Topic for $1 set by $2 on $stime($3).
on ^333 * {
  if ([${time() - [$3]}] < [172800]) {
    echo ### Topic for $1 set by $2 $tdiff(${time() - [$3]}) ago at $left(5 $word(3 $stime($3)))
  } {
    echo ### Topic for $1 set by $2 $tdiff(${time() - [$3]}) ago at $word(0 $strim($3)) $word(1 $stime($3)) $word(2 $stime($3))
  }
}
on ^317 * if (index(012345679 $3) != -1)
  {echo ### $1 has been idle for $tdiff($2)  Signon at $stime($3).}
  {echo ### $1 has been idle for $tdiff($2).}
on ^328 "*" if ([$ircURL]) {echo ### URL for $1 is $2-}
#on ^329 "*" echo ### $1: created $stime($2)
#on ^329 "*" echo $1: created $stime(${time() - [$2]}) ago at $left(5 $word(3 $stime($2)))
on ^329 "*" {
  if ([${time() - [$2]}] < [172800]) {
    echo $1 created $tdiff(${time() - [$2]}) ago at $left(5 $word(3 $stime($2)))
  } {
    echo $1 created $tdiff(${time() - [$2]}) ago at $word(0 $strim($2)) $word(1 $stime($2)) $word(2 $stime($2))
  }
}
on ^310 "*" echo ### $1 looks very helpful.


# The silence server functionality
alias silence quote silence
alias sile quote silence
on ^raw_irc "% SILENCE %" echo ### $*

# From MirclMax's irc2DALnet script
alias urlon {^assign ircURL ON;echo ### You will now see channel URLs.}
alias urloff {^assign -ircURL;echo ### You will no longer see channel URLs.}


# The following are commands to make better use of DALnet's features:

# Ignore floods from NickServ, ChanServ, MemoServ and HelpServ
on flood ^NickServ
on flood ^ChanServ
on flood ^MemoServ
on flood ^HelpServ
on flood ^OperServ

on ^notice "NickServ*" {echo #NickServ# $1-}
on ^notice "ChanServ*" {echo #ChanServ# $1-}
on ^notice "MemoServ*" {echo #MemoServ# $1-}
on ^notice "HelpServ*" {echo #HelpServ# $1-}
on ^notice "OperServ*" {echo #OperServ# $1-}
on ^notice "MemoServ New memo from*" {echo ### New memo from $4-}
on ^notice "MemoServ You have 1 new memo(s).*" {echo ### You have a new memo. $6-}
on ^notice "MemoServ You have % new memo(s).*" {echo ### You have $3 new memos. $6-}

# DALnet allows up to 30 character nicknames, this alias will not
# affect the nick command on other networks
alias nick quote nick :$*

set help_service HelpServ

# DALnet server aliases
alias ns ^msg NickServ@services.dal.net
alias cs ^msg ChanServ@services.dal.net
alias ms ^msg MemoServ@services.dal.net
alias hs ^msg HelpServ@services.dal.net
alias os ^msg OperServ@services.dal.net

# Send a memo
# Usage: /memo <nick> <message...>
alias memo msg MemoServ@services.dal.net SEND

# Channel functions: aop, sop, akick
# Usage: /aop <#channel> <what...>
#        /sop <#channel> <what...>
#        /akick <#channel> <what...>
alias aop ^msg ChanServ@services.dal.net AOP
alias sop ^msg ChanServ@services.dal.net SOP
alias akick ^msg ChanServ@services.dal.net AKICK


# Ghost alias by Wizzu
# Usage: /ghost <nick which is ghosted> [password if required]
alias ghost if ([$0]) {
  ^assign ghosted $0-
  msg NickServ@services.dal.net ghost $ghosted
  ^on #^notice 667 "NickServ Your ghost has been killed" {
    eval timer 1 nick $ghosted
    xecho -level crap ### Changing nickname to $ghosted
    cleanghost
  }
  ^on #^notice 667 "NickServ That nick isn't registered" cleanghost
  ^on #^notice 667 "NickServ No one is using that nick right now" cleanghost
  ^on #^notice 667 "NickServ Access denied" cleanghost
  ^alias cleanghost {
    ^assign -ghosted
    ^on #notice 667 -"NickServ Your ghost has been killed"
    ^on #notice 667 -"NickServ That nick isn't registered"
    ^on #notice 667 -"NickServ No one is using that nick right now"
    ^on #notice 667 -"NickServ Access denied"
    timer 1 ^alias -cleanghost
  } {
    xecho -level crap ### Usage: ${K}ghost <nick> [password if needed], kill your ghost with NickServ
  }
}


###############################################################
## Script to allow /leave channel with a message like /quit! ##
###############################################################

### DALnet LEAVE script, by Lefler
### Modified by Wizzu
### Lets you use comments on channel leave, for use with DALnet server
### software 2.8.21.mu3.dal3 and later. Fully compatible with other IRC
### servers.
###
### Use:
### /leave <channel> <comment>

alias part {
        if ([$1]) {quote part $0 :$1-}
                {quote part $0}
}
on -raw_irc "% PART *" {
        if ([$3]) {^assign partmsg $mid(1 1024 $3-)}
                {^assign -partmsg}
}

on ^leave "*" {
        if ([$partmsg]) {echo ### $0 left channel $1: $partmsg}
                {echo ### $0 has left channel $1.}
}



# This just to let know we loaded OK...
# Okay, maybe it looks rather grand -- so sue me!
echo ### DALnet handling functions now loaded.