#echo %%% Loading DALop...

# DALop and the companion loader script by Wizzu <wizzu@dal.net>


# aliases and functions:

# NewEcho, used to report stuff by script
alias ne xecho -level crap ###
# Opnote and wallop echo aliases
alias eopnote xecho -level opnote
alias ewallop xecho -level wallop

#dummy alias.. replace with what you want to do whenever a server splits
#useful for doing something when Services goes off
alias srvschk #

# A /who command to list all IRC Operators
alias iops ${K}${K}who -operators 0

# Servname. Trim the "xx.dal.net" from server names. From MirclMax.
# Modified by Wizzu (to work for any number of parameters)
alias servname {
  if ([$1]) {
    if (match(*.dal.net $0))
      { @ function_return = [$left($index(. $0) $0) ] ## [$servname($1-)] }
      { @ function_return = [$0 ] ## [$servname($1-) ] }
  } {
    if (match(*.dal.net $0))
      { @ function_return = [$left($index(. $0) $0)] }
      { @ function_return = [$0] }
  }
}

# Length. Returns length of string.
#alias length {@function_return = [$rindex($right(1 $0-) $0-)] + 1}
alias length {@ string = [$0-];@ function_return = [$@string];^assign -string}

# Trim. Drop first and last character from string.
alias trim {@ function_return = [$mid(1 ${[$length($0-)] - 2} $0-)]}


# The entire show script
#echo %%% Loading show.irc...

alias show_types {
  foreach show show_curr {
    @ show_keys = [$show_keys] ## [$show_curr ]
  }
  @ function_return = [$show_keys]
  ^assign -show_curr
  ^assign -show_keys
}

# add_show(show_key show_var alias_show_on alias_show_off description)
alias add_show {
  @ show[$0] = [$1 $2 $3 $encode($4-)]
}

alias show {
  if ([$0]) {
    if ([$1]) {
      ^assign showval $1
    } {
      ^assign showval ON
    }
    if (show[$0]) {
      if (([$showval]==[OFF])||([$showval]==[-])) {
        $word(2 $show[$0])
      } {
        $word(1 $show[$0])
      }
    } {
      xecho -level crap ### Unknown show type, types available: $show_types()
    }
    ^assign -showval
  } {
    eval xecho -level crap ### Show settings, ${K}show <type> to set on, ${K}show <type> OFF to set off
    foreach show show_curr {
      eval @ show_curr_val = [\$$word(0 $show[$show_curr])]
      if ([$show_curr_val]) {
        xecho -level crap ### [$show_curr] $decode($word(3 $show[$show_curr])) = $show_curr_val
      } {
        xecho -level crap ### [$show_curr] $decode($word(3 $show[$show_curr])) is off
      }
    }
    ^assign -show_curr_val
    ^assign -show_curr
  }
}


##### Start of included file: DALop


#echo %%% Loading DALop...
# This file is part of the "standard files" of WizIrc, and
# will be overwritten if you upgrade just by untarring the
# updated version of WizIrc over the old one.


# Features toggle
#urlon/urloff -- see the DALnet script
alias clientson {^assign showclients ON;ne Showing client connects/exits.}
alias clientsoff {^assign -showclients;ne Hiding client connects/exits.}
alias localon {^assign showlocal ON;ne Showing local server info.}
alias localoff {^assign -showlocal;ne Hiding local server info.}
alias collson {^assign showcolls ON;ne Showing collision kill messages.}
alias collsoff {^assign -showcolls;ne Hiding collision kill messages.}
alias servkillson {^assign showservkills ON;ne Showing regular Services kill messages.}
alias servkillsoff {^assign -showservkills;ne Hiding regular Services kill messages.}
alias killson {^assign showkills ON;ne Showing standard (non-services, non-collision) kill messages.}
alias killsoff {^assign -showkills;ne Hiding standard (non-services, non-collision) kill messages.}
alias autokillson {^assign showautokills ON;ne Showing Services autokill messages.}
alias autokillsoff {^assign -showautokills;ne Hiding Services autokill messages.}
alias cloneson {^assign clonewatch ON;ne Clonewatch enabled.}
alias clonesoff {^assign -clonewatch;ne Clonewatch disabled.}
alias neton {^assign shownet ON;ne Showing net status reports.}
alias netoff {^assign -shownet;ne Hiding net status reports.}
alias hackson {^assign showhacks ON;ne Showing hack reports and the like.}
alias hacksoff {^assign -showhacks;ne Hiding hack reports and the like.}
alias clonekillson {^assign showclonekills ON;ne Showing clonebot kill messages.}
alias clonekillsoff {^assign -showclonekills;ne Hiding clonebot kill messages.}
alias reporttime {if ([$0])
                     {^assign reporttime $0}
                     {eval ne Usage: ${K}reporttime <seconds>, set time between reports.}
                 }

if ([$reporttime]==[]) {reporttime 300}  # default 5 mins

# Userfriendlier usage
#assumes load show
add_show collkills showcolls collson collsoff Show collision kills
add_show servkills showservkills servkillson servkillsoff Show regular Services kills
add_show kills showkills killson killsoff Show standard kills
add_show autokills showautokills autokillson autokillsoff Show Services autokills
add_show clonekills showclonekills clonekillson clonekillsoff Show clonebot kills
add_show clients showclients clientson clientsoff Show client connects/exits
add_show net shownet neton netoff Net status reporting
add_show hacks showhacks hackson hacksoff Hack reporting
add_show local showlocal localon localoff Local server info


# DALnet features
alias os msg OperServ
alias kline quote kline $*
alias unkline quote unkline $*
alias globops quote globops :$*
# Wallops are in use again
#alias wallops globops
alias go globops
alias opchat globops CHAT: $0-
alias oc opchat


# aliases and functions:
alias c connect
alias die ne Please use ${K}terminateserver to really quit the server.
alias terminateserver ${K}${K}die
alias global {
  if ([$0]) {
    nick DALnet;notice \$*.net [Global Notice] $0- (Please do not reply.) -$N;nick $N
  } {
    eval ne Usage: ${K}global <global message>, sent to $$*.net
  }
}


# OperServ excempt from flood control
on flood ^OperServ


# IPtrim. Remove [aaa.bbb.ccc.ddd] from nick/hostname, if present.
alias iptrim if (index([ $0)>0)
  {@ function_return = [$left($rindex(\[ $0) $0)]}
  {@ function_return = [$0]}


alias linked {
  ^assign linker $0
  ^assign linked $1
  if (linked == linkwait[$encode($linker)]) {
    eopnote !G! ${aw}$servname($linked) --- $servname($linker)  Link established \(confirmed by $servname($linker)\)
    ^assign -linkwait[$encode($linker)]
  } {
    if (linked == linkold[$encode($linker)]) {
      eopnote !G! ${aw}$servname($linker) --- $servname($linked)  Link established (confirmation)
      ^assign -linkold[$encode($linker)]
    } {
      if (linkwait[$encode($linked)]) {
        eopnote !G! ${aw}$servname($linkwait[$encode($linked)]) --- $servname($linked)  Link established (unconfirmed, false)
      }
      if (shownet) {
        @ linkwait[$encode($linked)] = [$linker]
        timer 5 showlink $linker $linked
      }
    }
  }
  ^assign -linked
  ^assing -linker
}

alias showlink {
  ^assign sl_linker $0
  ^assign sl_linked $1
  if (sl_linker == linkwait[$encode($sl_linked)]) {
    # then no confirmation seen
    eopnote !G! ${aw}$servname($sl_linker) --- $servname($sl_linked)  Link established
    ^assign -linkwait[$encode($sl_linked)]
    @ linkold[$encode($sl_linked)] = [$sl_linker]
    timer 25 if \([$linkold[$encode($sl_linked)]]==[$sl_linker]\) \{^assign -linkold[$encode\($sl_linked\)]\}
  }
    # else confirmed and removed from wait list
    # or link already closed and removed from wait list
  ^assing -sl_linked
  ^assing -sl_linker
}


# ons:

# Stuff you can see when umode is +g (DALnet additional umode)

# Link established
on ^server_notice "% % GLOBAL -- from % Link with % established." {
  if ([$O]!=[]) {
    linked $strip(: $5) $iptrim($8)
  } {
    if (shownet) {
      eopnote !G! ${aw}$servname($strip(: $5)) --- $servname($iptrim($8))  Link established
    }
  }
}
# Link with services established
on ^server_notice "% % GLOBAL -- from % Link with services.dal.net% established." if (shownet) {
  eopnote !G! ${aw}$servname($strip(: $5)) --- $servname($iptrim($8))  Link established
}
# Remote closed connection
on ^server_notice "% % GLOBAL -- from % Server % closed the connection" if (shownet) {
  ^assign which $iptrim($7)
  showlink $strip(: $5) $which
  eopnote !G! ${aw}$servname($strip(: $5)) -X- $servname($which)  Remote closed connection
  srvschk $which
  ^assign -which
}
# No response, connection closed
on ^server_notice "% % GLOBAL -- from % No response from *" if (shownet) {
  ^assign closed $iptrim($9)
  showlink $strip(: $5) $closed
  eopnote !G! ${aw}$servname($strip(: $5)) -X- $servname($closed)  Link closed (no response)
  srvschk $closed
  ^assign -closed
}
# Connect attempt
on ^server_notice "% % GLOBAL -- from % Remote CONNECT *" if (shownet) {
  if ([$9]==[from]) {
    eopnote !G! ${aw}$servname($strip(: $5)) -?- $servname($8)  Connect attempt by $10
  } {
    eopnote !G! ${aw}$servname($strip(: $5)) -?- $servname($8) $9  Connect attempt by $11
  }
}
# Squit
on ^server_notice "% % GLOBAL -- from % Received SQUIT % from *" if (shownet) {
  ^assign from $iptrim($10)
  if ([\($from\)]==[$11]) {
    showlink $strip(: $5) $8
    eopnote !G! ${aw}$servname($strip(: $5)) -X- $servname($8)  Squit from $servname($from)
  } {
    if (match(\(*\) $11-)) {
      ^assign reason $trim($11-)
    } {
      ^assign reason $11-
    }
    showlink $strip(: $5) $8
    eopnote !G! ${aw}$servname($strip(: $5)) -X- $servname($8)  Squit from $servname($from) $reason
    ^assign -reason
  }
  srvschk $8
  ^assign -from
}
# Error
on ^server_notice "% % GLOBAL -- from % ERROR from *" if (shownet) {
  eopnote !G! ${aw}$servname($0): ERROR from $servname($iptrim($8)): $7-
}
# Error, connection closed
on ^server_notice "% % GLOBAL -- from % ERROR from % -- Closing Link: *" if (shownet) {
  ^assign from $iptrim($8)
  ^assign closed $iptrim($12)
  if ((left(1 $13)==[\(])&&(right(1 $13-)==[\)])) {
    ^assign error $trim($13-)
  } {
    ^assign error $13-
  }
  showlink $from $closed
  eopnote !G! ${aw}$servname($from) -X- $servname($closed)  Closing link \(Error: $error\)
  srvschk $closed
  ^assign -error
  ^assign -closed
  ^assign -from
}
# Link cancelled
on ^server_notice "% % GLOBAL -- from % Link % cancelled, server *" if (shownet) {
  #^assign connector $right(${index(@ $7) - 1} $left($index(@ $7) $7))
  if (match([*] $7)) {
    ^assign connector $trim($7)
  } {
    ^assign connector $7
  }
  if (match(*.dal.net[*] $connector)) {@ connector = [$iptrim($connector)]}
  showlink $strip(: $5) $10
  eopnote !G! ${aw}$servname($strip(: $5)) -_- $servname($10)  Link by $servname($connector) cancelled (server already exists)
  ^assign -connector
}

# Nick collision
on ^server_notice "% % GLOBAL -- Nick collision on % % % <- % %" {
  ^assign collhost $iptrim($11)
  if ([$collhost]==[services.dal.net]) {
    if ([$showservkills]) {
      if ([$7]!=[$strip(\( $8)]) {
        eopnote !G! ${aw}$7 killed by NickServ \($servname($strip(\( $8)) <-\)
      } {
        eopnote !G! ${aw}$7 killed by NickServ
      }
    }
  } {
    if ([$showcolls]) {
      if ([$12]==[0\)]) {
        if ([$7]!=[$strip(\( $8)]) {
          eopnote !G! ${aw}Nick collision on $7 \($servname($strip(\( $8)) <- $servname($collhost)\)
        } {
          eopnote !G! ${aw}Nick collision on $7 from $servname($collhost)
        }
      } {
        ^assign colldiff ${[$9] - [$strip(\(\) $12)]}
        if ([$colldiff]<[0]) {@ colldiff = [${[$colldiff] * -1}]}
        ^assign colltime $tdiff($colldiff)
        ^assign colltarget $strip(\( $8)
        if ([$7]!=[$colltarget]) {
          eopnote !G! ${aw}Nick collision on $7 \($servname($colltarget) <- $servname($collhost) $colltime\)
        } {
          eopnote !G! ${aw}Nick collision on $7 \(<- $servname($collhost) $colltime\)
        }
        ^assign -colltarget
        ^assign -colldiff
        ^assign -colltime
      }
    }
  }
  ^assign -collhost
}
# Failed oper attempt
on ^server_notice "% % GLOBAL -- from % Failed OPER attempt by *" if (showhacks) {
  eopnote !G! ${aw}Failed OPER attempt by $10 <$trim($11)> at $servname($strip(: $5)) $12
}
# User trying to become server
on ^server_notice "% % GLOBAL -- from % User % trying to become a server %" if (showhacks) {
  eopnote !G! ${aw}User $left($rindex([ $7) $7) <$trim($right(${[$length($7)] - index([ $7)} $7))> trying to become server $13 at $servname($strip(: $5))
}

# Services notices:
# Clone alert from Services
on ^server_notice "% % GLOBAL -- from services.dal.net: Clone Alert: *" {
  eopnote !G! ${aw}Services: Clone Alert: $8-
}
# Services warnings/debug notices
on ^server_notice "% % GLOBAL -- from services.dal.net: User % desynched from services during %" if (showhacks) {
  eopnote !G! ${aw}Services: $6-
}
on ^server_notice "% % GLOBAL -- from services.dal.net: MODE for unknown %" if (showhacks) {
  eopnote !G! ${aw}Services: $6-
}
on ^server_notice "% % GLOBAL -- from services.dal.net: % leaves non-existent *" if (showhacks) {
  eopnote !G! ${aw}Services: $6-
}


#!N! Nick change collision from _Pale_ to Pale (dragon.ut.us.dal.net 83044834
#    <- rutgers.nj.us.dal.net[128.6.46.3] 830448795)

# Stuff you can see when umode is +s

# Write error, connection closed
on ^server_notice "% % NOTICE -- Write error to *" if (shownet) {
  ^assign closed $iptrim($7)
  showlink $0 $closed
  eopnote !N! ${aw}$servname($0) -X- $servname($closed)  Link closed (write error)
  srvschk $closed
  ^assign -closed
}
# Connection activated
on ^server_notice "% % NOTICE -- Connection to % activated*" if (shownet) {
  eopnote !N! ${aw}$servname($0) -?- $servname($iptrim($6))  Connection activated
}
# Link established
on ^server_notice "% % NOTICE -- Link with % established." {
  if ([$O]!=[]) {
    linked $0 $iptrim($6)
  } {
    if (shownet) {
      eopnote !N! ${aw}$servname($0) --- $servname($iptrim($6))  Link established
    }
  }
}

# Someone going +o
on ^server_notice "% % NOTICE -- % % is now operator*" if (showlocal) {
  eopnote !N! ${aw}$4 <$trim($5)> is now operator on $servname($0)
}

# Squit
on ^server_notice "% % NOTICE -- Received SQUIT % from *" if (shownet) {
  ^assign from $iptrim($8)
  if ([\($from\)]==[$9]) {
    showlink $0 $6
    eopnote !N! ${aw}$servname($0) -X- $servname($6)  Squit from $servname($from)
  } {
    if (match(\(*\) $9-)) {
      ^assign reason $trim($9-)
    } {
      ^assign reason $9-
    }
    showlink $0 $6
    eopnote !N! ${aw}$servname($0) -X- $servname($6)  Squit from $servname($from) $reason
    ^assign -reason
  }
  srvschk $6
  ^assign -from
}
# Error
on ^server_notice "% % NOTICE -- ERROR :from *" if (shownet) {
  ^assign from $iptrim($6)
  eopnote !N! ${aw}ERROR from $servname($from) $7-
  ^assign -from
}
# Error, connection closed
on ^server_notice "% % NOTICE -- ERROR :from % -- Closing Link: *" if (shownet) {
  ^assign from $iptrim($6)
  ^assign closed $iptrim($10)
  if ((left(1 $11)==[\(])&&(right(1 $11-)==[\)])) {
    ^assign error $trim($11-)
  } {
    ^assign error $11-
  }
  showlink $from $closed
  eopnote !N! ${aw}$servname($from) -X- $servname($closed)  Closing link \(Error: $error\)
  srvschk $closed
  ^assign -error
  ^assign -closed
  ^assign -from
}
# Remote closed connection
on ^server_notice "% % NOTICE -- Server % closed the connection" if (shownet) {
  ^assign which $iptrim($5)
  showlink $0 $which
  eopnote !N! ${aw}$servname($0) -X- $servname($which)  Remote closed connection
  srvschk $which
  ^assign -which
}

# Link cancelled
on ^server_notice "% % NOTICE -- Link % cancelled, server *" if (shownet) {
  #^assign connector $right(${index(@ $5) - 1} $left($index(@ $5) $5))
  if (match([*] $5)) {
    ^assign connector $trim($5)
  } {
    ^assign connector $5
  }
  showlink $0 $8
  eopnote !N! ${aw}$servname($0) -_- $servname($8)  Link by $connector cancelled (server already exists)
  ^assign -connector
}
# Lost connect
on ^server_notice "% % NOTICE -- Lost connection to *" if (shownet) {
  ^assign lost $iptrim($7)
  ^assign reason $right(${[$length($7)] - index(: $7) + 1} $7) $8-
  showlink $0 $lost
  eopnote !N! ${aw}$servname($0) -X- $servname($lost)  Lost connect \($reason\)
  srvschk $lost
  ^assign -lost
  ^assign -reason
}
# Connection failed
on ^server_notice "% % NOTICE -- Connect to host % failed: *" if (shownet) {
  ^assign failed $iptrim($7)
  ^assign reason $9-
  showlink $0 $failed
  eopnote !N! ${aw}$servname($0) -_- $servname($failed)  Connection failed \($reason\)
  ^assign -lost
  ^assign -reason
}
# No response, connection closed
on ^server_notice "% % NOTICE -- No response from *" if (shownet) {
  ^assign closed $iptrim($7)
  showlink $0 $closed
  eopnote !N! ${aw}$servname($0) -X- $servname($closed)  Link closed (no response)
  srvschk $closed
  ^assign -closed
}
# Server dropped
on ^server_notice "% % NOTICE -- Dropping server *" if (shownet) {
  ^assign dropped $6
  showlink $0 $dropped
  eopnote !N! ${aw}$servname($0) -X- $servname($dropped)  Server dropped
  ^assign -dropped
}
# Client connect
on ^server_notice "% % NOTICE -- Client connecting*" if (showclients) {
  if ([$7]==[port]) {
    eopnote !N! ${aw}Connect port $8 $9 <$trim($10)>
  } {
    eopnote !N! ${aw}Connect: $6 <$trim($7)>
  }
}
# Client exit
on ^server_notice "% % NOTICE -- Client exiting: *" if (showclients) {
  ^assign enick $6
  ^assign eaddr $trim($7)
  if ([$8]==[[]]) {
    eopnote !N! ${aw}Exit: $enick <$eaddr>
  } {
    ^assign emsg $trim($8-)
    #if (([$word(2 $emsg)]==[<-])||([$word(4 $emsg)]==[<-])) {
    if (match(<- $emsg)) {
      eopnote !N! ${aw}Exit: $enick <$eaddr> (Collision kill)
    } {
      if ([$emsg]==[($enick)]) {
        eopnote !N! ${aw}Exit: $enick <$eaddr>
      } {
        eopnote !N! ${aw}Exit: $enick <$eaddr> \($emsg\)
      }
    }
    ^assign -emsg
  }
  ^assign -enick
  ^assign -eaddr
}
# Unknown nick (desynch) kills
# hades.se.DAL.net *** Notice -- Received KILL message for SOID. From farside.tx.us.DAL.net Path: toronto.on.ca.dal.net[198.133.36.85]!farside.tx.us.DAL.net[204.214.136.7]!farside.tx.us.DAL.net (Smoky(?) <- toronto.on.ca.dal.net[198.133.36.153])
on ^server_notice "% % NOTICE -- Received KILL message for % From % Path: %.dal.net %(?) <- *" if ([$showcolls]) {
  eopnote !N! ${aw}Desynch kill for $strip(. $8) from $servname($iptrim($strip(\) $15)))
}
on ^server_notice "% % NOTICE -- Received KILL message for % From % Path: %.dal.net (%dal.net[%] Self collision)" if ([$showcolls]) {
  eopnote !N! ${aw}Self collision for $strip(. $8) on $servname($iptrim($strip(\( $13)))
}

# Kill notice
on ^server_notice "% % NOTICE -- Received KILL message for *" {
  ^assign killed $strip(. $8)
  ^assign killer $10
  ^assign killreason $13-
  if ([$match(services.dal.net* $killreason)]) {
    if ([$showservkills]) {
      eopnote !N! ${aw}${killed} killed by Services
      #eopnote !N! ${aw}${killed} killed by Services \($servname($killer)\)
    }
  } {
    if ([$14]==[<-]) {
      if ([$showcolls]) {
        ^assign colltarget $strip(\(\) $13)
        ^assign collsource $killer
        ^assign killer $iptrim($strip(\) $15))
        if ([$killed]!=[$colltarget]) {
          ^assign killreason $servname($colltarget) <- $servname($collsource)
        } {
          ^assign killreason <- $servname($collsource)
        }
        eopnote !N! ${aw}Collision kill for $killed from $servname($killer) \(${killreason}\)
        ^assign -collsource
        ^assign -colltarget
      }
    } {
      if ([$killer]!=[NickServ]) {
        if ([$showkills]) {
          if ([$killer]==[services.dal.net]) {
            if ([$killreason]==[(User banned from network)]) {
              if ([$showautokills]) {
                eopnote !N! ${aw}${killed} autokilled by Services
              }
            } {
              #(Your username (*) (not your nickname) is hostile, please change to one that doesn't contain *, @, ~, or !)
              #if ([$killreason]==[(Your username is hostile, please change to one that doesn't contain *, ~, or !)])
              if ([$13-14 $16-]==[(Your username (not your nickname) is hostile, please change to one that doesn't contain *, @, ~, or !)]) {
                if ([$showservkills]) {
                  eopnote !N! ${aw}${killed} killed by Services (Hostile username)
                }
              } {
                #if ([$showservkills]) {
                  eopnote !N! ${aw}$killed killed by Services ${killreason}
                #}
              }
            } 
          } {
            # actual oper kill, optionally filter out clone kills
            if ((match(*cloning* $killreason)) || (match(*clone* $killreason))) {
              # operator clone kill (most likely)
              if (showclonekills) {
                eopnote !N! ${aw}${killed} killed by $killer ${killreason}
              }
            } {
              # regular operator kill
              eopnote !N! ${aw}${killed} killed by $killer ${killreason}
            }
          }
        }
      } {
        if ([$showservkills]) {
          eopnote !N! ${aw}${killed} killed by $killer ${killreason}
        }
      }
    }
  }
  ^assign -killed
  ^assign -killer
  ^assign -killreason
}

# Nick change collision
on ^server_notice "% % NOTICE -- Nick change collision from % to % % % <- % %" if ([$showcolls]) {
  if ([$strip(\) $15)]>[0]) {
    eopnote !G! ${aw}Nick collision on $10 \(was $8\) \($servname($strip(\( $11)) <- $servname($14)\)
  } {
    ^assign colltime $tdiff(${[$9] - [$strip(\(\) $15)]})
    eopnote !G! ${aw}Nick collision on $10 \(was $8\) \($servname($strip(\( $11)) <- $servname($14) $colltime\)
    ^assign -colltime
  }
}

# Cannot accept connection
on ^server_notice "% % NOTICE -- Cannot accept connections *" if (showclients) {
  ^assign host $left($index(: $7) $7)
  ^assign reason $right(${[$length($7-)] - index(: $7-) + 1} $7-)
  eopnote !N! ${aw}Cannot accept connection at $servname($host) \($reason\)
  ^assign -reason
  ^assign -host
}

#!N! Unauthorized connection from Mullson[mull119@dialup69.pgh.sgi.net].
#!N! MShome added a temp k:line for *@*aone.net.au unauthorized bot

# Too many connections
on ^server_notice "% % NOTICE -- Too many connections from %" if (showlocal) {
  if ([$reported[iline]]==[]) {
    if ([$reporttime]) {
      eopnote !N! ${aw}Server full (I:line), connect attempt by $8 \(Suppressing these messages for $reporttime seconds.\)
      timer $reporttime ^assign -reported[iline]
      ^assign reported[iline] YES
    } {
      eopnote !N! ${aw}Server full (I:line), connect attempt by $8
    }
  }
}
# All connections in use
#!N! All connections in use. (cin.il.us.dal.net[@0.0.0.0.6667])
on ^server_notice "% % NOTICE -- All connections in use. (%)" if (showlocal) {
  if ([$reported[maxconn]]==[]) {
    ^assign thisserv $iptrim($trim($8))
    ^assign portn $strip(\]\) $right(${[$length($8)] - rindex(. $8) + 1} $8))
    if ([$reporttime]) {
      eopnote !N! ${aw}Server full (max connections), connect attempt to $servname($thisserv):$portn \(Suppressing these messages for $reporttime seconds.\)
      timer $reporttime ^assign -reported[maxconn]
      ^assign reported[maxconn] YES
    } {
      eopnote !N! ${aw}Server full (max connections), connect attempt to $servname($thisserv):$portn
    }
    ^assign -portn
    ^assign -thisserv
  }
}
# IP mismatch
#!N! IP# Mismatch: 205.216.168.42 != s13-pm01.sierra.campus.mci.net[2aa8dbcd]
on ^server_notice "% % NOTICE -- IP# Mismatch: % != %" if (showclients) {
  eopnote !N! ${aw}IP# Mismatch, $6 != $8
}
# Connect failure
on ^server_notice "% % NOTICE -- connect failure: *" if (showclients) {
  ^assign failed $iptrim($6)
  ^assign reason $right(${[$length($7-)] - rindex(: $7-) + 1} $7-)
  eopnote !N! ${aw}Connection failed for $failed \($reason\)
  ^assign -reason
  ^assign -failed
}
# Failed connect attempt
on ^server_notice "% % NOTICE -- Failed in connecting to *" if (showclients) {
  ^assign host $left($index([ $8) $8)
  ^assign port $strip(]. $right(${[$length($8)] - rindex(. $8)} $8))
  ^assign reason $right(${[$length($9-)] - rindex(: $9-) + 1} $9-)
  eopnote !N! ${aw}Failed connect to $servname($host):$port \($reason\)
  ^assign -reason
  ^assign -port
  ^assign -host
}
# User trying to become server
on ^server_notice "% % NOTICE -- User % trying to become a server %" if (showhacks) {
  ^assign host $0
  ^assign nick $left($rindex([ $5) $5)
  ^assign address $trim($right(${[$length($5)] - index([ $5)} $5))
  eopnote !N! ${aw}User $nick <$address> trying to become server $11 at $servname($host)
  ^assign -address
  ^assign -nick
  ^assign -host
}

# Net.ride
on ^server_notice "% % NOTICE -- NET.RIDE *" if (showhacks) {
  eopnote !N! ${aw}$4-
}
# Hack(2)
on ^server_notice "% % NOTICE -- HACK(2): % MODE *" if (showhacks) {
  eopnote !N! ${aw}$4-
}
# Bounce or hack(3)
on ^server_notice "% % NOTICE -- BOUNCE or HACK(3): % MODE *" if (showhacks) {
  eopnote !N! ${aw}$4-
}
# Bad USER param count
#!N! bad USER param count for Super_Sim from igc.fl.us.dal.net[207.89.0.30]
on ^server_notice "% % NOTICE -- bad USER param count for % from %" if (showhacks) {
  eopnote !N! ${aw}$dalserv($iptrim($11)): Bad USER param count for $9
}

# No "NOTICE --" leader
on ^server_notice "% % Connecting to %" {
  ^assign connserver $right(${length($4) - rindex([ $4) + 1} $4)
  ^assign connserver $left($index(] $connserver) $connserver)
  eopnote !N! ${aw}$servname($0) -?- $servname($connserver)  Local connect attempt
  ^assign -connserver
}



# Stuff you can see when umode is +w

# Link established
on ^wallop "% S Link with % established." if (shownet) {
  ^assign linked $iptrim($4)
  ewallop !W! ${aw}$servname($0) --- $servname($linked)  Link established
  ^assign -linked
}
# No response, connection closed
on ^wallop "% S No response from *" if (shownet) {
  ^assign closed $iptrim($5)
  showlink $0 $closed
  ewallop !W! ${aw}$servname($0) -X- $servname($closed)  Link closed (no response)
  srvschk $closed
  ^assign -closed
}
# Connect attempt
on ^wallop "% S Remote CONNECT *" if (shownet) {
  ^assign which $4 $5
  ^assign from $7
  ewallop !W! ${aw}$servname($0) -?- $servname($which)  Connect attempt by ${from}
  ^assign -which
  ^assign -from
}
# Remote closed connection
on ^wallop "% S Server % closed the connection" if (shownet) {
  ^assign which $iptrim($3)
  showlink $0 $which
  ewallop !W! ${aw}$servname($0) -X- $servname($which)  Remote closed connection
  srvschk $which
  ^assign -which
}
# Squit
on ^wallop "% S Received SQUIT % from *" if (shownet) {
  ^assign from $iptrim($6)
  if ([\($from\)]==[$7]) {
    ewallop !W! ${aw}$servname($0) -X- $servname($4)  ^BSquit^B from $from
  } {
    ewallop !W! ${aw}$servname($0) -X- $servname($4)  ^BSquit^B from $from $7-
  }
  showlink $0 $4
  srvschk $4
  ^assign -from
}

# Hack
on ^wallop "% S HACK: *" if (showhacks) {
  ewallop !W! ${aw}$servname($0) \($servname($3) hack\): $4-
}

# DALnet services.dal.net wallop
on ^wallop "services.dal.net S *" ewallop !W! ${aw}Services: $2-
# Regular Wallop
on ^wallop "*" ewallop !W! ${aw}$0 \($1\): $2-


# Other global notice
on ^server_notice "% % GLOBAL -- from *" {
  if (match(%.% $5)) {
    if ([$5]!=[services.dal.net:]) {
      eopnote !G! ${aw}$servname($strip(: $5)): $6-
    } {
      eopnote !G! ${aw}Services: $6-
    }
  } {
    if ([$6]==[/me]) {
      eopnote !G! ${aw}* $strip(: $5) $7-
    } {
      if (([$5]==[$7]) && ([$6]==[*])) {
        eopnote !G! ${aw}* $strip(: $5) $8-
      } {
        eopnote !G! ${aw}$5-
      }
    }
    if (BELL) {if (!ISAWAY) {beep}}
  }
}
#igc: ERROR from igc.fl.us.dal.net[205.198.244.30] -- Closing Link:
#[198.60.22.5] (Server Exists)

# Services oper notice
on ^server_notice "% % OPER -- from services.dal.net: *" {
  eopnote !O! ${aw}Services: $6-
}
# Other oper notice
on ^server_notice "% % OPER -- from *" {
  eopnote !O! ${aw}$servname($strip(: $5)): $6-
}


# Other server notice
on ^server_notice "% % NOTICE -- *" if (shownet) {
  eopnote !N! ${aw}$4-
}
on ^server_notice "% % *" {
  if ([$1]==[***]) {
    ne $2-
  } {
    eopnote !N! ${aw}$1-
  }
}
# *** Notice -- Received unauthorized connection from
#     toronto2.on.ca.dal.netÄ@zip.io.orgÅ.
# *** Notice -- Unauthorized connection from NetPulseÄ152.163.152.100Å.
# *** Notice -- Server igc.fl.us.dal.net already present from igc.fl.us.dal.net


# Operator wallop
on ^wallop "% + *" {
  if ([$BELL]) {beep}
  ewallop !W! $0: $2-
}
# User wallop
on ^wallop "% - *" {
  if ([$BELL]) {beep}
  ewallop !W! $0: $2-
}


# Help system stuff
#on ^server_notice "% *** HelpOp -- from % (HelpOp): *" {
#  if (bell) {beep}
#  xecho -level MSG [Help] $5-
#}
#on ^server_notice "% *** HelpOp -- from % (local): *" {
#  if (bell) {beep}
#  xecho -level MSG [Help] $5-
#}
on ^server_notice "% *** HelpOp -- from *" {
  if (BELL) {if (!ISAWAY) {beep}}
  xecho -level MSG ${aw}[Help] $5 $6-
}


on ^382 "%.% % Rehashing" echo ### $servname($0): Rehashing $1
on ^382 * echo ### $servname($0): $1-


##### End of included file: DALop


eval xecho -level crap ### DALop by Wizzu loaded. (29-Jun-96)  To get started, try ${K}show
eval xecho -level crap ### Commands: global kline unkline globops iops show