#echo %%% Loading akillsrch.irc...

# Date last modified: 5 Jun 1996

alias akillsrch {
  if (![$akillsearch]) {
    if ([$0]) {
      ^assign akillsearch $0-
      ^on ^notice "OperServ ? %!%@%.%" {
        if (rmatch($1 $akillsearch)) {
          xecho -levep crap #OperServ#   $1
          @ akill_srch_found = akill_srch_found + 1
        }
        @ akill_srch_count = akill_srch_count + 1
      }
      ^on ^notice "OperServ End of list" {
        xecho -level crap #OperServ# End of list \(matched ${akill_srch_found}/${akill_srch_count}, search: $akillsearch\)
        clear_akillsrch
      }
      ^on -notice "OperServ Sorry, only operators can use this service" {
        clear_akillsrch
        xecho -level crap ### Autokill search cancelled.
      }
      @ akill_srch_found = [0]
      msg OperServ autokill
    } {
      eval xecho -level crap ### Usage: ${K}akillsrch <search pattern(s)>
    }
  } {
    eval xecho -level crap ### Another autokill search is running. Use ${K}reaks to set another search pattern.
  }
}

alias clear_akillsrch {
  ^on ^notice -"OperServ End of list"
  ^on ^notice -"OperServ Sorry, only operators can use this service"
  ^on ^notice -"OperServ ? %!%@%.%"
  assign -akill_srch_found
  assign -akill_srch_count
  assign -akillsearch
}

alias reakillsrch {
  if ([$0]) {
    if ([$akillsearch]) {
      ^assign akillsearch $0-
      xecho -level crap ### Autokill search pattern set to $0-.
    } {
      xecho -level crap ### No autokill search is currently active.
    }
  } {
    eval xecho -level crap ### Usage: ${K}reaks <new search pattern(s)>
  }
}

alias aks akillsrch
alias reaks reakillsrch

eval xecho -level crap ### Autokill search by Wizzu, 5-Jun-96. Usage: ${K}aks <search pattern(s)>