########################################################################
## Kickban script written by MirclMax, and improved by Worf and Wizzu ##
########################################################################

#KickBan
#Modified by Worf
#Further modifications by Wizzu, 1996: Feb 17th, Apr 4th, Apr 10th, Jun 19

#kickban     usage: /kb <nick> [<kick message>]
#siteban     usage: /sb <nick> [<kick message>]
#"just" ban  usage: /ban <nick>
#unban       usage: /ub <nick>
# (sorry no unban for /siteban yet - tell me if you figure a good name
#  for it *grin*)

# returns *.bar.org for foo.bar.org, *zapf.net for zapf.net,
# 11.22.33.* for 11.22.33.44
alias hostmask {
  ^assign hn $0
  if ([$strip(0123456789. $hn)]!=[]) {
    # normal hostname
    @ function_return = [*$right(${@hn - rindex(. $left($rindex(. $hn) $hn))} $hn)]
  } {
    # IP address
    @ function_return = [$left(${rindex(. $hn) + 1} $hn)*]
  }
  ^assign -hn
}

alias kb kickban
alias kickban userhost $0 -cmd do_kickban $$0 $$3 $$4 $1-
alias do_kickban {
  if ([$1]!=[<UNKNOWN>]) {
    if (onchannel($0 $C)) {
      mode $C -o+b $0 *!*$strip(~ $1)@$hostmask($2)
      kick $C $0 $3-
    } {
      mode $C +b *!*$strip(~ $1)@$hostmask($2)
    }
  }
  {echo ### $0 is not available for kickbanning.}
}

alias sb siteban
alias siteban userhost $0 -cmd do_siteban $$0 $$4 $1-
alias do_siteban {
  if ([$1]!=[<UNKNOWN>]) {
    if (onchannel($0 $C)) {
      mode $C -o+b $0 *!*@$hostmask($1)
      kick $C $0 $3-
    } {
      mode $C +b *!*@$hostmask($1)
    }
  }
  {echo ### $0 is not available for kickbanning.}
}

alias ub unban
alias unban userhost $0 -cmd do_unban $$0 $$3 $$4 $0
alias do_unban {
  if ([$1]!=[<UNKNOWN>]) {
    mode $C -b *!*$strip(~ $1)@$hostmask($2)
  }
  {echo ### $0 is not available for unbanning.}
}

alias ban userhost $0 -cmd do_ban $$0 $$3 $$4 $0
alias do_ban {
  if ([$1]!=[<UNKNOWN>]) {
    mode $C +b *!*$strip(~ $1)@$hostmask($2)
  }
  {echo ### $0 is not available for banning.}
}

xecho -level crap ### Kickban by MirclMax/Worf/Wizzu loaded (Apr 19th 96)
eval xecho -level crap ### Usage: ${K}kb <nick> [kick message], ${K}sb <nick> [kick message], ${K}ban <nick> and ${K}ub <nick>