# Pager, show a page request.
# Usage: other party can do /msg <your nick> !page <level: 1-10> <reason>

# Concept and original source from BluRaven, source modified by Wizzu.
# Date: 22-Apr-96

alias page {
  if (([$2])&&([$strip(0123456789 $2)]==[])) {
    echo  
    echo ###############  *****    ****    *****   ******  ********  ###############
    echo ###############  *    *  *    *  *     *  *        ******   ###############
    echo ###############  *****   *    *  *        ****      ****    ###############
    echo ###############  *       ******  *  ****  *          **     ###############
    echo ###############  *       *    *  *     *  *                 ###############
    echo ###############  *       *    *   *****   ******     **     ###############
    if ([$noisypage]) {
      echo 
    } {
      echo  
    }
    if ([$2]<[11]) {
      if ([$2]>[0]) {
       ^assign imp $2
      } {
       # 0 or less
        ^assign imp 1
      }
    } {
      # over 10
      ^assign imp 10
    }
    @ left_m = [$imp] - 1
    @ right_m = 10 - [$imp]
    @ meter = [----------]
    echo PAGE BY:  $0  at  ${Z}  IMPORTANCE: $left($left_m $meter)*$right($right_m $meter) \($2 of 10\)
    echo REASON: $3-
    echo  
    notice $0 Your page request at level $2 and reason "$3-" has been received.
    # always good to remove any assigns you used when they aren't needed anymore
    ^assign -imp
    ^assign -left_m
    ^assign -right_m
    ^assign -meter
  } {
    if ([$2]) {notice $0 Error, level should be numeric.}
    notice $0 Usage: /msg $N !page <level: 1-10> <reason>
  }
}
on ^msg "% !page*" page $0-
^assign noisypage ON

alias pagenoisy {
  xecho -level crap ### Pager will now beep.
  ^assign noisypage ON
}
alias pagesilent {
  xecho -level crap ### Pager will now be silent.
  ^assign -noisypage
}
alias pagestatus {
  if ([$noisypage]) {
    xecho -level crap ### Pager will beep.
  } {
    xecho -level crap ### Pager is silent.
  }
}

eval xecho -level crap ### Pager loaded. By BluRaven and Wizzu, 22-Apr-96. Initially set to noisy.
eval xecho -level crap ### Usage: ${K}pagenoisy  ${K}pagesilent  ${K}pagestatus
eval xecho -level crap ### Others can do: /msg $N !page <level: 1-10> <reason>